miércoles, 16 de enero de 2013

Hallar el primer y el último día hábil del mes

En un artículo antiguo estudiamos la manera de utilizar las funciones DIA.LAB, DIA.LAB.INTL, DIAS.LABDIAS.LAB.INTL. Hoy vamos a utilizarlas para calcular el primer y el último día hábil de cada mes.

En B3 pondremos el año y en B5:B23 los días festivos de ese año. En las columnas E y F calcularemos el primer día laborable de cada mes y el último.



En el primer ejemplo, consideraremos que son festivos los sábado, los domingos y los días señalados en B5:B23. Posteriormente haremos otro ejemplo en el que serán festivos los lunes, martes, viernes y los días del rango B5:B23.

En E5:
=DIA.LAB(FECHA($B$3;FILA(A1);1)-1;1;$B$6:$B$23)   

Extendemos la fórmula hasta la fila 16.

El truco consiste en situarnos en el último día del mes anterior. Por ejemplo, en enero, la función FECHA($B$3;FILA(A1);1)-1 equivale a FECHA(2013;1;1)-1; o lo que lo mismo: 1/1/2013 menos un día, lo que nos lleva al 31 de diciembre de 2012. Así pues, la fórmula de E5 es equivalente a DIA.LAB(31 de diciembre de 2012;1;$B$6:$B$23). DIA.LAB nos remite al primer día laborable después del 31/12/2012 (es el 1 del segundo argumento). Como el 1/1/2013 es festivo (es el primer día del rango B5:B23) busca el siguiente; es decir, el 2/1/2013, que no es festivo y, por tanto, éste será el primer día laborable de enero de 2013.

El razonamiento para calcular el último día laborable del mes es parecido, aunque, en este caso tendremos que situarnos en el primer día del mes siguiente y restarle uno.

En F5:
=DIA.LAB(FECHA($B$3;FILA(A1)+1;1);-1;$B$6:$B$23)

Extendemos la fórmula hasta la fila 16.

Para calcular el primer y último día laborable del mes, siendo festivos los lunes, martes y viernes, es necesario usar la función DIA.LAB.INTL (no disponible en Excel 2003 y 2007).



En E5:
=DIA.LAB.INTL(FECHA($B$3;FILA(A1);1)-1;1;"1100100";$B$6:$B$23) 

En F5:
=DIA.LAB.INTL(FECHA($B$3;FILA(A1)+1;1);-1;"1100100";$B$6:$B$23)
Extendemos ambas fórmulas hasta la fila 16.

Descargar archivo (SE1-Primer y último habil.xlsx)

Descargar archivo (SE1-Primer y último habil.xls)


No hay comentarios:

Publicar un comentario