Cálculo de la fecha de la Pascua de Resurección

La Pascua de Resurrección es la celebración cristiana que conmemora la resurrección de Jesucristo. La fecha de celebración varía entre el 22 de marzo y el 25 de abril, ya que tiene lugar el domingo siguiente a la primera luna llena de primavera del hemisferio norte.

Esta fiesta determina el calendario móvil de otras fiestas: así la Ascensión (el ascenso de Jesús al cielo) se celebra 40 días después de Pascua, y Pentecostés 10 días después de la Ascensión. La semana anterior a la Pascua de Resurrección es la Semana Santa, que comienza con el Domingo de Ramos (que conmemora la entrada triunfal de Jesús en Jerusalén). La Octava de Pascua (popularmente conocida como "semana de Pascua") es la semana que sucede a este Domingo de Pascua (o Domingo de Resurrección). El tiempo pascual o tiempo de Pascua designa, en la liturgia católica, las semanas que van desde el Domingo de Resurrección hasta el de Pentecostés.

La forma más sencilla de calcular la fecha del domingo de Pascua es mediante la fórmula desarrollada por el matemático alemán Johann Carl Friedrich Gauss (30 de abril de 1777, Brunswick – 23 de febrero de 1855, Göttingen).

Llamaremos A al año en el que queremos calcular la fecha de la Pascua de Resurrección. De la tabla siguiente, obtendremos dos parámetros, M y N . Por ejemplo, al año 2010 le corresponde M = 24 y N = 5

Ya tenemos los tres datos básicos. Ahora, mediante fórmulas sencillas obtendremos otros cinco datos. Les llamaremos: a, b, c, d y e.

A continuación, se muestran las fórmulas que hay que utilizar y un ejemplo. El año elegido es el 2010.
























Se pueden dar dos casos:

1)      Si (d + e < 10) la Pascua será el día (d + e + 22) de marzo.

2)      Si (d + e > 9) la Pascua será el día (d + e − 9) de abril.

Hay dos excepciones:

• Si la fecha obtenida es el 26 de abril, entonces, la Pascua será el 19 de abril.
• Si la fecha obtenida es el 25 de abril, con d = 28, e = 6 y a > 10, entonces, la Pascua será el 18 de abril.

Sigamos con nuestro cálculo:

d + e = 13. Es mayor que nueve. Se aplica el segundo caso.

d + e − 9 = 4. La Pascua es el 4 de abril, que no coincide con ninguna de las dos excepciones.

Ya tenemos toda la información necesaria para crear la aplicación que nos permita obtener la fecha de la Pascua de Resurrección.

Diseñamos una hoja que contenga la tabla para obtener M y N, así como celdas donde almacenar los valores de a, b, c, d y e.

A la celda K4 le aplicamos un formato de fecha adecuado. Para ello, estando en K4, pulsamos Ctrl + 1 y, en la pestaña Número del cuadro de diálogo Formato de celdas, seleccionamos el siguiente formato de fecha: *miércoles, 14 de marzo de 2001.





























En B4 escribimos el año; por ejemplo, 2010

En C4:

=BUSCARV(B4;$M$4:$P$9;3;VERDADERO)    [Resultado: 24]

En D4:

=BUSCARV(B4;$M$4:$P$9;4;VERDADERO)     [Resultado: 5]

En E4:

=RESIDUO(B4;19)     [Resultado: 15]

En F4:

=RESIDUO(B4;4)    [Resultado: 2]

En G4:

=RESIDUO(B4;7)    [Resultado: 1]

En H4:

=RESIDUO(19*E4+C4;30)    [Resultado: 9]

En I4:

=RESIDUO(2*F4+4*G4+6*H4+D4;7)    [Resultado: 4]

En J4:

=H4+I4    [Resultado: 13]

En K4:

=SI(J4<10;FECHA(B4;3;J4+22);SI(J4-9=26;FECHA(B4;4;19);SI(Y(J4-9=25;H4=28;I4=6;E4>10);FECHA(B4;4;18);FECHA(B4;4;J4-9))))    [Resultado: domingo, 04 de abril de 2010]

Copiando las fórmulas hacia abajo obtendremos la fecha de la Pascua de años sucesivos.

Estudiando la hoja, podemos comprobar que, por ejemplo, 1954 y 2076 son años en los que se dan las excepciones señaladas más arriba.

Descargar archivo (S25-Pascua Resurrección.xls)

Descargar archivo (S25-Pascua Resurrección.xlsx)