Mostrar imágenes

Voy a describir una técnica para mostrar la foto de un tenista elegido de una lista desplegable. La lista la pondremos en la celda H19 y encima, la fotografía. Añadiremos su posición en el ranking de la ATP, los puntos que lleva acumulados y los torneos jugados (datos del 24 de junio de 2011).

En la columna B de la hoja Fotos, ponemos los nombres y nacionalidades de los jugadores; en la columna C, sus fotografías.

Hacemos clic en la celda H19 de la hoja ATP y accedemos a Datos + Validación de datos. En la ficha Configuración, ponemos una lista con los valores del rango C3:C32.

En la lista de H19, elegimos un nombre; por ejemplo: Nadal, Rafael (ESP)

A continuación, creamos un "nombre" accediendo a Fórmulas + Asignar nombre. El nombre será Foto_tenista y la fórmula: =DESREF(Fotos!$C$3;COINCIDIR(ATP!$H$19;ATP!$C$3:$C$32;0)-1;0;1;1)

En la hoja Fotos, hacemos clic en la fotografía de Roger Federer y pulsamos Ctrl + C.
En la hoja ATP, hacemos clic en la celda G10 (vale cualquier otra) y pulsamos Ctrl + V.
Hacemos clic en la fotografías de Federer y, en la barra de fórmulas, escribimos: =Foto_tenista

Como en H19 habíamos elegido Nadal, Rafael (ESP), la fotografía de Federer habrá sido sustituida por la de Nadal. Cada vez que cambiemos de jugador, se mostrará su fotografía.

Arrastramos y agrandamos la fotografía hasta colocarla en la posición deseada.

Para terminar, vamos a poner la posición del jugador en el ranking de la ATP, los puntos y los torneos.

Hacemos clic en H15, pulsamos Ctrl + 1 para acceder a la ventana Formato de celdas, y ponemos el siguiente formato personalizado: "Ranking: " #.##0"º"

Del mismo modo, en H16 ponemos el formato: "Puntos: " #.##0
Finalmente, en H17 el formato será: "Torneos: " #.##0

En H15:

=INDICE($B$3:$B$32;COINCIDIR($H$19;$C$3:$C$32;);1)

En H16:

=INDICE($D$3:$D$32;COINCIDIR($H$19;$C$3:$C$32;);1)

En H17:

=INDICE($E$3:$E$32;COINCIDIR($H$19;$C$3:$C$32;);1)

Descargar archivo (S78-Ranking de la ATP.xls)

Descargar archivo (S78-Ranking de la ATP.xlsx)