lunes, 11 de junio de 2012

¿Cuántos miércoles hay entre dos fechas?

Vamos a calcular el número de miércoles (o cualquier otro día de la semana) que hay entre dos fechas. Los únicos datos que dispondremos serán la fecha inicial (B2), la fecha final (B3) y el día de la semana (B4).

En D2:E6 obtendremos diversos valores intermedios que nos servirán para poner la fórmula definitiva en B6.

Supongamos que la fecha inicial es el 5 de junio de 2012, la final, el 27 de junio de 2012 y el día elegido, el miércoles.

Comenzaremos obteniendo en E2 el día de la semana de la fecha inicial.

En E2:
=DIASEM(B2;2)    [Resultado: 2]

El siguiente paso consistirá en calcular los días que hay entre las dos fechas.

En E3:
=B3-B2    [Resultado: 22]

Ahora, calcularemos las semanas completas que hay entre la fecha inicial y la final.

En E4:
=COCIENTE(E3;7)     [Resultado: 3]

Nota: En Excel 2003 la función COCIENTE sólo está disponible si está cargado el complemento Herramientas para análisis (Herramientas + Complementos + Herramientas para análisis). Si no queremos usar COCIENTE, la fórmula se puede sustituir por: =ENTERO(E3/7)

Tres semanas completas significa que hay 3 miércoles, pero aún queda 1 día más, que podría tocar miércoles, con lo que el número total de miércoles sería 4. Para comprobarlo, necesitamos calcular los días sobrantes.

En E5:
=RESIDUO(E3;7)    [Resultado: 1]

Para saber si alguno de los días sobrantes (en nuestro caso sólo hay uno) cae en miércoles, debemos calcular el número de la semana que le corresponde al miércoles (el día que hayamos elegido en B4).

En E6:
=COINCIDIR(B4;{"lunes";"martes";"miércoles";"jueves";"viernes";"sábado";"domingo"};0)   [Resultado: 3]

Ya tenemos todos los datos necesarios: hay tres semanas completas, lo que significa que hay tres miércoles (valor de la celda E4), y un día adicional (pueden haber hasta seis días adicionales) que hay que comprobar si es miércoles. Si lo es, se añade un día más; en caso contrario, se añaden cero días.

En B6:
=E4+SI(Y(E2<=E6;E2+E5>=E6);1;SI((E2+E5-7)>=E6;1;0))    [Resultado: 4]

 
 
 

No hay comentarios:

Publicar un comentario